mirror of
https://git.postgresql.org/git/postgresql.git
synced 2024-09-13 19:19:39 +02:00
fa8fbadb93
When building without --enable-dtrace, emit dummy
do {} while (0)
statements for the stubbed-out TRACE_POSTGRESQL_foo() macros
instead of empty macros that totally elide the original probe
statement.
This fixes the
warning: suggest braces around empty body in an ‘if’ statement [-Wempty-body]
introduced by b94409a02f
.
Author: Craig Ringer <craig.ringer@2ndquadrant.com>
Discussion: https://www.postgresql.org/message-id/flat/20210504221531.cfvpmmdfsou6eitb%40alap3.anarazel.de
25 lines
1.2 KiB
Sed
25 lines
1.2 KiB
Sed
#-------------------------------------------------------------------------
|
|
# sed script to create dummy probes.h file when dtrace is not available
|
|
#
|
|
# Copyright (c) 2008-2021, PostgreSQL Global Development Group
|
|
#
|
|
# src/backend/utils/Gen_dummy_probes.sed
|
|
#-------------------------------------------------------------------------
|
|
|
|
/^[ ]*probe /!d
|
|
s/^[ ]*probe \([^(]*\)\(.*\);/\1\2/
|
|
s/__/_/g
|
|
y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/
|
|
s/^/#define TRACE_POSTGRESQL_/
|
|
s/([^,)]\{1,\})/(INT1)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3, INT4)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3, INT4, INT5)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3, INT4, INT5, INT6)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3, INT4, INT5, INT6, INT7)/
|
|
s/([^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\}, [^,)]\{1,\})/(INT1, INT2, INT3, INT4, INT5, INT6, INT7, INT8)/
|
|
s/$/ do {} while (0)/
|
|
P
|
|
s/(.*$/_ENABLED() (0)/
|