mirror of
https://git.postgresql.org/git/postgresql.git
synced 2024-08-09 17:53:24 +02:00
bbfd7edae5
Until now __attribute__() was defined to be empty for all compilers but gcc. That's problematic because it prevents using it in other compilers; which is necessary e.g. for atomics portability. It's also just generally dubious to do so in a header as widely included as c.h. Instead add pg_attribute_format_arg, pg_attribute_printf, pg_attribute_noreturn macros which are implemented in the compilers that understand them. Also add pg_attribute_noreturn and pg_attribute_packed, but don't provide fallbacks, since they can affect functionality. This means that external code that, possibly unwittingly, relied on __attribute__ defined to be empty on !gcc compilers may now run into warnings or errors on those compilers. But there shouldn't be many occurances of that and it's hard to work around... Discussion: 54B58BA3.8040302@ohmu.fi Author: Oskari Saarenmaa, with some minor changes by me.
121 lines
2.6 KiB
Plaintext
121 lines
2.6 KiB
Plaintext
%{
|
|
/*
|
|
* A scanner for EMP-style numeric ranges
|
|
* contrib/cube/cubescan.l
|
|
*/
|
|
|
|
#include "postgres.h"
|
|
|
|
/* No reason to constrain amount of data slurped */
|
|
#define YY_READ_BUF_SIZE 16777216
|
|
|
|
/* Avoid exit() on fatal scanner errors (a bit ugly -- see yy_fatal_error) */
|
|
#undef fprintf
|
|
#define fprintf(file, fmt, msg) fprintf_to_ereport(fmt, msg)
|
|
|
|
static void
|
|
fprintf_to_ereport(const char *fmt, const char *msg)
|
|
{
|
|
ereport(ERROR, (errmsg_internal("%s", msg)));
|
|
}
|
|
|
|
/* Handles to the buffer that the lexer uses internally */
|
|
static YY_BUFFER_STATE scanbufhandle;
|
|
/* this is now declared in cubeparse.y: */
|
|
/* static char *scanbuf; */
|
|
/* static int scanbuflen; */
|
|
|
|
/* flex 2.5.4 doesn't bother with a decl for this */
|
|
int cube_yylex(void);
|
|
|
|
void cube_scanner_init(const char *str);
|
|
void cube_scanner_finish(void);
|
|
%}
|
|
|
|
%option 8bit
|
|
%option never-interactive
|
|
%option nodefault
|
|
%option noinput
|
|
%option nounput
|
|
%option noyywrap
|
|
%option warn
|
|
%option prefix="cube_yy"
|
|
|
|
|
|
n [0-9]+
|
|
integer [+-]?{n}
|
|
real [+-]?({n}\.{n}?|\.{n})
|
|
float ({integer}|{real})([eE]{integer})?
|
|
|
|
%%
|
|
|
|
{float} yylval = yytext; return CUBEFLOAT;
|
|
\[ yylval = "("; return O_BRACKET;
|
|
\] yylval = ")"; return C_BRACKET;
|
|
\( yylval = "("; return O_PAREN;
|
|
\) yylval = ")"; return C_PAREN;
|
|
\, yylval = ")"; return COMMA;
|
|
[ \t\n\r\f]+ /* discard spaces */
|
|
. return yytext[0]; /* alert parser of the garbage */
|
|
|
|
%%
|
|
|
|
void pg_attribute_noreturn
|
|
yyerror(NDBOX **result, const char *message)
|
|
{
|
|
if (*yytext == YY_END_OF_BUFFER_CHAR)
|
|
{
|
|
ereport(ERROR,
|
|
(errcode(ERRCODE_SYNTAX_ERROR),
|
|
errmsg("bad cube representation"),
|
|
/* translator: %s is typically "syntax error" */
|
|
errdetail("%s at end of input", message)));
|
|
}
|
|
else
|
|
{
|
|
ereport(ERROR,
|
|
(errcode(ERRCODE_SYNTAX_ERROR),
|
|
errmsg("bad cube representation"),
|
|
/* translator: first %s is typically "syntax error" */
|
|
errdetail("%s at or near \"%s\"", message, yytext)));
|
|
}
|
|
}
|
|
|
|
|
|
/*
|
|
* Called before any actual parsing is done
|
|
*/
|
|
void
|
|
cube_scanner_init(const char *str)
|
|
{
|
|
Size slen = strlen(str);
|
|
|
|
/*
|
|
* Might be left over after ereport()
|
|
*/
|
|
if (YY_CURRENT_BUFFER)
|
|
yy_delete_buffer(YY_CURRENT_BUFFER);
|
|
|
|
/*
|
|
* Make a scan buffer with special termination needed by flex.
|
|
*/
|
|
scanbuflen = slen;
|
|
scanbuf = palloc(slen + 2);
|
|
memcpy(scanbuf, str, slen);
|
|
scanbuf[slen] = scanbuf[slen + 1] = YY_END_OF_BUFFER_CHAR;
|
|
scanbufhandle = yy_scan_buffer(scanbuf, slen + 2);
|
|
|
|
BEGIN(INITIAL);
|
|
}
|
|
|
|
|
|
/*
|
|
* Called after parsing is done to clean up after cube_scanner_init()
|
|
*/
|
|
void
|
|
cube_scanner_finish(void)
|
|
{
|
|
yy_delete_buffer(scanbufhandle);
|
|
pfree(scanbuf);
|
|
}
|