mirror of
https://github.com/yuzu-emu/yuzu.git
synced 2024-08-20 00:33:23 +02:00
This implements some missing network APIs including a large chunk of the SSL service, enough for Mario Maker (with an appropriate mod applied) to connect to the fan server [Open Course World](https://opencourse.world/). Connecting to first-party servers is out of scope of this PR and is a minefield I'd rather not step into. ## TLS TLS is implemented with multiple backends depending on the system's 'native' TLS library. Currently there are two backends: Schannel for Windows, and OpenSSL for Linux. (In reality Linux is a bit of a free-for-all where there's no one 'native' library, but OpenSSL is the closest it gets.) On macOS the 'native' library is SecureTransport but that isn't implemented in this PR. (Instead, all non-Windows OSes will use OpenSSL unless disabled with `-DENABLE_OPENSSL=OFF`.) Why have multiple backends instead of just using a single library, especially given that Yuzu already embeds mbedtls for cryptographic algorithms? Well, I tried implementing this on mbedtls first, but the problem is TLS policies - mainly trusted certificate policies, and to a lesser extent trusted algorithms, SSL versions, etc. ...In practice, the chance that someone is going to conduct a man-in-the-middle attack on a third-party game server is pretty low, but I'm a security nerd so I like to do the right security things. My base assumption is that we want to use the host system's TLS policies. An alternative would be to more closely emulate the Switch's TLS implementation (which is based on NSS). But for one thing, I don't feel like reverse engineering it. And I'd argue that for third-party servers such as Open Course World, it's theoretically preferable to use the system's policies rather than the Switch's, for two reasons 1. Someday the Switch will stop being updated, and the trusted cert list, algorithms, etc. will start to go stale, but users will still want to connect to third-party servers, and there's no reason they shouldn't have up-to-date security when doing so. At that point, homebrew users on actual hardware may patch the TLS implementation, but for emulators it's simpler to just use the host's stack. 2. Also, it's good to respect any custom certificate policies the user may have added systemwide. For example, they may have added custom trusted CAs in order to use TLS debugging tools or pass through corporate MitM middleboxes. Or they may have removed some CAs that are normally trusted out of paranoia. Note that this policy wouldn't work as-is for connecting to first-party servers, because some of them serve certificates based on Nintendo's own CA rather than a publicly trusted one. However, this could probably be solved easily by using appropriate APIs to adding Nintendo's CA as an alternate trusted cert for Yuzu's connections. That is not implemented in this PR because, again, first-party servers are out of scope. (If anything I'd rather have an option to _block_ connections to Nintendo servers, but that's not implemented here.) To use the host's TLS policies, there are three theoretical options: a) Import the host's trusted certificate list into a cross-platform TLS library (presumably mbedtls). b) Use the native TLS library to verify certificates but use a cross-platform TLS library for everything else. c) Use the native TLS library for everything. Two problems with option a). First, importing the trusted certificate list at minimum requires a bunch of platform-specific code, which mbedtls does not have built in. Interestingly, OpenSSL recently gained the ability to import the Windows certificate trust store... but that leads to the second problem, which is that a list of trusted certificates is [not expressive enough](https://bugs.archlinux.org/task/41909) to express a modern certificate trust policy. For example, Windows has the concept of [explicitly distrusted certificates](https://learn.microsoft.com/en-us/previous-versions/windows/it-pro/windows-server-2012-r2-and-2012/dn265983(v=ws.11)), and macOS requires Certificate Transparency validation for some certificates with complex rules for when it's required. Option b) (using native library just to verify certs) is probably feasible, but it would miss aspects of TLS policy other than trusted certs (like allowed algorithms), and in any case it might well require writing more code, not less, compared to using the native library for everything. So I ended up at option c), using the native library for everything. What I'd *really* prefer would be to use a third-party library that does option c) for me. Rust has a good library for this, [native-tls](https://docs.rs/native-tls/latest/native_tls/). I did search, but I couldn't find a good option in the C or C++ ecosystem, at least not any that wasn't part of some much larger framework. I was surprised - isn't this a pretty common use case? Well, many applications only need TLS for HTTPS, and they can use libcurl, which has a TLS abstraction layer internally but doesn't expose it. Other applications only support a single TLS library, or use one of the aforementioned larger frameworks, or are platform-specific to begin with, or of course are written in a non-C/C++ language, most of which have some canonical choice for TLS. But there are also many applications that have a set of TLS backends just like this; it's just that nobody has gone ahead and abstracted the pattern into a library, at least not a widespread one. Amusingly, there is one TLS abstraction layer that Yuzu already bundles: the one in ffmpeg. But it is missing some features that would be needed to use it here (like reusing an existing socket rather than managing the socket itself). Though, that does mean that the wiki's build instructions for Linux (and macOS for some reason?) already recommend installing OpenSSL, so no need to update those. ## Other APIs implemented - Sockets: - GetSockOpt(`SO_ERROR`) - SetSockOpt(`SO_NOSIGPIPE`) (stub, I have no idea what this does on Switch) - `DuplicateSocket` (because the SSL sysmodule calls it internally) - More `PollEvents` values - NSD: - `Resolve` and `ResolveEx` (stub, good enough for Open Course World and probably most third-party servers, but not first-party) - SFDNSRES: - `GetHostByNameRequest` and `GetHostByNameRequestWithOptions` - `ResolverSetOptionRequest` (stub) ## Fixes - Parts of the socket code were previously allocating a `sockaddr` object on the stack when calling functions that take a `sockaddr*` (e.g. `accept`). This might seem like the right thing to do to avoid illegal aliasing, but in fact `sockaddr` is not guaranteed to be large enough to hold any particular type of address, only the header. This worked in practice because in practice `sockaddr` is the same size as `sockaddr_in`, but it's not how the API is meant to be used. I changed this to allocate an `sockaddr_in` on the stack and `reinterpret_cast` it. I could try to do something cleverer with `aligned_storage`, but casting is the idiomatic way to use these particular APIs, so it's really the system's responsibility to avoid any aliasing issues. - I rewrote most of the `GetAddrInfoRequest[WithOptions]` implementation. The old implementation invoked the host's getaddrinfo directly from sfdnsres.cpp, and directly passed through the host's socket type, protocol, etc. values rather than looking up the corresponding constants on the Switch. To be fair, these constants don't tend to actually vary across systems, but still... I added a wrapper for `getaddrinfo` in `internal_network/network.cpp` similar to the ones for other socket APIs, and changed the `GetAddrInfoRequest` implementation to use it. While I was at it, I rewrote the serialization to use the same approach I used to implement `GetHostByNameRequest`, because it reduces the number of size calculations. While doing so I removed `AF_INET6` support because the Switch doesn't support IPv6; it might be nice to support IPv6 anyway, but that would have to apply to all of the socket APIs. I also corrected the IPC wrappers for `GetAddrInfoRequest` and `GetAddrInfoRequestWithOptions` based on reverse engineering and hardware testing. Every call to `GetAddrInfoRequestWithOptions` returns *four* different error codes (IPC status, getaddrinfo error code, netdb error code, and errno), and `GetAddrInfoRequest` returns three of those but in a different order, and it doesn't really matter but the existing implementation was a bit off, as I discovered while testing `GetHostByNameRequest`. - The new serialization code is based on two simple helper functions: ```cpp template <typename T> static void Append(std::vector<u8>& vec, T t); void AppendNulTerminated(std::vector<u8>& vec, std::string_view str); ``` I was thinking there must be existing functions somewhere that assist with serialization/deserialization of binary data, but all I could find was the helper methods in `IOFile` and `HLERequestContext`, not anything that could be used with a generic byte buffer. If I'm not missing something, then maybe I should move the above functions to a new header in `common`... right now they're just sitting in `sfdnsres.cpp` where they're used. - Not a fix, but `SocketBase::Recv`/`Send` is changed to use `std::span<u8>` rather than `std::vector<u8>&` to avoid needing to copy the data to/from a vector when those methods are called from the TLS implementation.
693 lines
27 KiB
CMake
693 lines
27 KiB
CMake
# SPDX-FileCopyrightText: 2018 yuzu Emulator Project
|
|
# SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
cmake_minimum_required(VERSION 3.22)
|
|
|
|
project(yuzu)
|
|
|
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMakeModules")
|
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/externals/cmake-modules")
|
|
|
|
include(DownloadExternals)
|
|
include(CMakeDependentOption)
|
|
include(CTest)
|
|
include(FetchContent)
|
|
|
|
# Set bundled sdl2/qt as dependent options.
|
|
# OFF by default, but if ENABLE_SDL2 and MSVC are true then ON
|
|
option(ENABLE_SDL2 "Enable the SDL2 frontend" ON)
|
|
CMAKE_DEPENDENT_OPTION(YUZU_USE_BUNDLED_SDL2 "Download bundled SDL2 binaries" ON "ENABLE_SDL2;MSVC" OFF)
|
|
# On Linux system SDL2 is likely to be lacking HIDAPI support which have drawbacks but is needed for SDL motion
|
|
CMAKE_DEPENDENT_OPTION(YUZU_USE_EXTERNAL_SDL2 "Compile external SDL2" ON "ENABLE_SDL2;NOT MSVC" OFF)
|
|
|
|
cmake_dependent_option(ENABLE_LIBUSB "Enable the use of LibUSB" ON "NOT ANDROID" OFF)
|
|
|
|
option(ENABLE_OPENGL "Enable OpenGL" ON)
|
|
mark_as_advanced(FORCE ENABLE_OPENGL)
|
|
option(ENABLE_QT "Enable the Qt frontend" ON)
|
|
option(ENABLE_QT6 "Allow usage of Qt6 to be attempted" OFF)
|
|
set(QT6_LOCATION "" CACHE PATH "Additional Location to search for Qt6 libraries like C:/Qt/6.3.1/msvc2019_64/")
|
|
|
|
option(ENABLE_QT_TRANSLATION "Enable translations for the Qt frontend" OFF)
|
|
CMAKE_DEPENDENT_OPTION(YUZU_USE_BUNDLED_QT "Download bundled Qt binaries" "${MSVC}" "ENABLE_QT" OFF)
|
|
|
|
option(ENABLE_WEB_SERVICE "Enable web services (telemetry, etc.)" ON)
|
|
|
|
option(YUZU_USE_BUNDLED_FFMPEG "Download/Build bundled FFmpeg" "${WIN32}")
|
|
|
|
option(YUZU_USE_EXTERNAL_VULKAN_HEADERS "Use Vulkan-Headers from externals" ON)
|
|
|
|
option(YUZU_USE_QT_MULTIMEDIA "Use QtMultimedia for Camera" OFF)
|
|
|
|
option(YUZU_USE_QT_WEB_ENGINE "Use QtWebEngine for web applet implementation" OFF)
|
|
|
|
option(ENABLE_CUBEB "Enables the cubeb audio backend" ON)
|
|
|
|
option(USE_DISCORD_PRESENCE "Enables Discord Rich Presence" OFF)
|
|
|
|
option(YUZU_TESTS "Compile tests" "${BUILD_TESTING}")
|
|
|
|
option(YUZU_USE_PRECOMPILED_HEADERS "Use precompiled headers" ON)
|
|
|
|
cmake_dependent_option(YUZU_ROOM "Compile LDN room server" ON "NOT ANDROID" OFF)
|
|
|
|
CMAKE_DEPENDENT_OPTION(YUZU_CRASH_DUMPS "Compile Windows crash dump (Minidump) support" OFF "WIN32" OFF)
|
|
|
|
option(YUZU_USE_BUNDLED_VCPKG "Use vcpkg for yuzu dependencies" "${MSVC}")
|
|
|
|
option(YUZU_CHECK_SUBMODULES "Check if submodules are present" ON)
|
|
|
|
option(YUZU_ENABLE_LTO "Enable link-time optimization" OFF)
|
|
|
|
option(YUZU_DOWNLOAD_TIME_ZONE_DATA "Always download time zone binaries" OFF)
|
|
|
|
CMAKE_DEPENDENT_OPTION(YUZU_USE_FASTER_LD "Check if a faster linker is available" ON "NOT WIN32" OFF)
|
|
|
|
CMAKE_DEPENDENT_OPTION(ENABLE_OPENSSL "Enable OpenSSL backend for ISslConnection" ON "NOT WIN32" OFF)
|
|
|
|
# On Android, fetch and compile libcxx before doing anything else
|
|
if (ANDROID)
|
|
set(CMAKE_SKIP_INSTALL_RULES ON)
|
|
set(LLVM_VERSION "15.0.6")
|
|
|
|
# Note: even though libcxx and libcxxabi have separate releases on the project page,
|
|
# the separated releases cannot be compiled. Only in-tree builds work. Therefore we
|
|
# must fetch the source release for the entire llvm tree.
|
|
FetchContent_Declare(llvm
|
|
URL "https://github.com/llvm/llvm-project/releases/download/llvmorg-${LLVM_VERSION}/llvm-project-${LLVM_VERSION}.src.tar.xz"
|
|
URL_HASH SHA256=9d53ad04dc60cb7b30e810faf64c5ab8157dadef46c8766f67f286238256ff92
|
|
TLS_VERIFY TRUE
|
|
)
|
|
FetchContent_MakeAvailable(llvm)
|
|
|
|
# libcxx has support for most of the range library, but it's gated behind a flag:
|
|
add_compile_definitions(_LIBCPP_ENABLE_EXPERIMENTAL)
|
|
|
|
# Disable standard header inclusion
|
|
set(ANDROID_STL "none")
|
|
|
|
# libcxxabi
|
|
set(LIBCXXABI_INCLUDE_TESTS OFF)
|
|
set(LIBCXXABI_ENABLE_SHARED FALSE)
|
|
set(LIBCXXABI_ENABLE_STATIC TRUE)
|
|
set(LIBCXXABI_LIBCXX_INCLUDES "${LIBCXX_TARGET_INCLUDE_DIRECTORY}" CACHE STRING "" FORCE)
|
|
add_subdirectory("${llvm_SOURCE_DIR}/libcxxabi" "${llvm_BINARY_DIR}/libcxxabi")
|
|
link_libraries(cxxabi_static)
|
|
|
|
# libcxx
|
|
set(LIBCXX_ABI_NAMESPACE "__ndk1" CACHE STRING "" FORCE)
|
|
set(LIBCXX_CXX_ABI "libcxxabi")
|
|
set(LIBCXX_INCLUDE_TESTS OFF)
|
|
set(LIBCXX_INCLUDE_BENCHMARKS OFF)
|
|
set(LIBCXX_INCLUDE_DOCS OFF)
|
|
set(LIBCXX_ENABLE_SHARED FALSE)
|
|
set(LIBCXX_ENABLE_STATIC TRUE)
|
|
set(LIBCXX_ENABLE_ASSERTIONS FALSE)
|
|
add_subdirectory("${llvm_SOURCE_DIR}/libcxx" "${llvm_BINARY_DIR}/libcxx")
|
|
set_target_properties(cxx-headers PROPERTIES INTERFACE_COMPILE_OPTIONS "-isystem${CMAKE_BINARY_DIR}/${LIBCXX_INSTALL_INCLUDE_DIR}")
|
|
link_libraries(cxx_static cxx-headers)
|
|
endif()
|
|
|
|
if (YUZU_USE_BUNDLED_VCPKG)
|
|
if (ANDROID)
|
|
set(ENV{ANDROID_NDK_HOME} "${ANDROID_NDK}")
|
|
list(APPEND VCPKG_MANIFEST_FEATURES "android")
|
|
|
|
if (CMAKE_ANDROID_ARCH_ABI STREQUAL "arm64-v8a")
|
|
set(VCPKG_TARGET_TRIPLET "arm64-android")
|
|
# this is to avoid CMake using the host pkg-config to find the host
|
|
# libraries when building for Android targets
|
|
set(PKG_CONFIG_EXECUTABLE "aarch64-none-linux-android-pkg-config" CACHE FILEPATH "" FORCE)
|
|
elseif (CMAKE_ANDROID_ARCH_ABI STREQUAL "x86_64")
|
|
set(VCPKG_TARGET_TRIPLET "x64-android")
|
|
set(PKG_CONFIG_EXECUTABLE "x86_64-none-linux-android-pkg-config" CACHE FILEPATH "" FORCE)
|
|
else()
|
|
message(FATAL_ERROR "Unsupported Android architecture ${CMAKE_ANDROID_ARCH_ABI}")
|
|
endif()
|
|
endif()
|
|
|
|
if (YUZU_TESTS)
|
|
list(APPEND VCPKG_MANIFEST_FEATURES "yuzu-tests")
|
|
endif()
|
|
if (YUZU_CRASH_DUMPS)
|
|
list(APPEND VCPKG_MANIFEST_FEATURES "dbghelp")
|
|
endif()
|
|
if (ENABLE_WEB_SERVICE)
|
|
list(APPEND VCPKG_MANIFEST_FEATURES "web-service")
|
|
endif()
|
|
|
|
include(${CMAKE_SOURCE_DIR}/externals/vcpkg/scripts/buildsystems/vcpkg.cmake)
|
|
elseif(NOT "$ENV{VCPKG_TOOLCHAIN_FILE}" STREQUAL "")
|
|
# Disable manifest mode (use vcpkg classic mode) when using a custom vcpkg installation
|
|
option(VCPKG_MANIFEST_MODE "")
|
|
include("$ENV{VCPKG_TOOLCHAIN_FILE}")
|
|
endif()
|
|
|
|
if (YUZU_USE_PRECOMPILED_HEADERS)
|
|
if (MSVC AND CCACHE)
|
|
# buildcache does not properly cache PCH files, leading to compilation errors.
|
|
# See https://github.com/mbitsnbites/buildcache/discussions/230
|
|
message(WARNING "buildcache does not properly support Precompiled Headers. Disabling PCH")
|
|
set(DYNARMIC_USE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
|
|
set(YUZU_USE_PRECOMPILED_HEADERS OFF CACHE BOOL "" FORCE)
|
|
endif()
|
|
endif()
|
|
if (YUZU_USE_PRECOMPILED_HEADERS)
|
|
message(STATUS "Using Precompiled Headers.")
|
|
set(CMAKE_PCH_INSTANTIATE_TEMPLATES ON)
|
|
endif()
|
|
|
|
|
|
# Default to a Release build
|
|
get_property(IS_MULTI_CONFIG GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
|
|
if (NOT IS_MULTI_CONFIG AND NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
|
|
message(STATUS "Defaulting to a Release build")
|
|
endif()
|
|
|
|
if(EXISTS ${PROJECT_SOURCE_DIR}/hooks/pre-commit AND NOT EXISTS ${PROJECT_SOURCE_DIR}/.git/hooks/pre-commit)
|
|
if (EXISTS ${PROJECT_SOURCE_DIR}/.git/)
|
|
message(STATUS "Copying pre-commit hook")
|
|
file(COPY hooks/pre-commit DESTINATION ${PROJECT_SOURCE_DIR}/.git/hooks)
|
|
endif()
|
|
endif()
|
|
|
|
# Sanity check : Check that all submodules are present
|
|
# =======================================================================
|
|
|
|
function(check_submodules_present)
|
|
file(READ "${PROJECT_SOURCE_DIR}/.gitmodules" gitmodules)
|
|
string(REGEX MATCHALL "path *= *[^ \t\r\n]*" gitmodules ${gitmodules})
|
|
foreach(module ${gitmodules})
|
|
string(REGEX REPLACE "path *= *" "" module ${module})
|
|
if (NOT EXISTS "${PROJECT_SOURCE_DIR}/${module}/.git")
|
|
message(FATAL_ERROR "Git submodule ${module} not found. "
|
|
"Please run: \ngit submodule update --init --recursive")
|
|
endif()
|
|
endforeach()
|
|
endfunction()
|
|
|
|
if(EXISTS ${PROJECT_SOURCE_DIR}/.gitmodules AND YUZU_CHECK_SUBMODULES)
|
|
check_submodules_present()
|
|
endif()
|
|
configure_file(${PROJECT_SOURCE_DIR}/dist/compatibility_list/compatibility_list.qrc
|
|
${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.qrc
|
|
COPYONLY)
|
|
if (EXISTS ${PROJECT_SOURCE_DIR}/dist/compatibility_list/compatibility_list.json)
|
|
configure_file("${PROJECT_SOURCE_DIR}/dist/compatibility_list/compatibility_list.json"
|
|
"${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.json"
|
|
COPYONLY)
|
|
endif()
|
|
if (ENABLE_COMPATIBILITY_LIST_DOWNLOAD AND NOT EXISTS ${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.json)
|
|
message(STATUS "Downloading compatibility list for yuzu...")
|
|
file(DOWNLOAD
|
|
https://api.yuzu-emu.org/gamedb/
|
|
"${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.json" SHOW_PROGRESS)
|
|
endif()
|
|
if (NOT EXISTS ${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.json)
|
|
file(WRITE ${PROJECT_BINARY_DIR}/dist/compatibility_list/compatibility_list.json "")
|
|
endif()
|
|
|
|
# Detect current compilation architecture and create standard definitions
|
|
# =======================================================================
|
|
|
|
include(CheckSymbolExists)
|
|
function(detect_architecture symbol arch)
|
|
if (NOT DEFINED ARCHITECTURE)
|
|
set(CMAKE_REQUIRED_QUIET 1)
|
|
check_symbol_exists("${symbol}" "" ARCHITECTURE_${arch})
|
|
unset(CMAKE_REQUIRED_QUIET)
|
|
|
|
# The output variable needs to be unique across invocations otherwise
|
|
# CMake's crazy scope rules will keep it defined
|
|
if (ARCHITECTURE_${arch})
|
|
set(ARCHITECTURE "${arch}" PARENT_SCOPE)
|
|
set(ARCHITECTURE_${arch} 1 PARENT_SCOPE)
|
|
add_definitions(-DARCHITECTURE_${arch}=1)
|
|
endif()
|
|
endif()
|
|
endfunction()
|
|
|
|
if (NOT ENABLE_GENERIC)
|
|
if (MSVC)
|
|
detect_architecture("_M_AMD64" x86_64)
|
|
detect_architecture("_M_IX86" x86)
|
|
detect_architecture("_M_ARM" arm)
|
|
detect_architecture("_M_ARM64" arm64)
|
|
else()
|
|
detect_architecture("__x86_64__" x86_64)
|
|
detect_architecture("__i386__" x86)
|
|
detect_architecture("__arm__" arm)
|
|
detect_architecture("__aarch64__" arm64)
|
|
endif()
|
|
endif()
|
|
|
|
if (NOT DEFINED ARCHITECTURE)
|
|
set(ARCHITECTURE "GENERIC")
|
|
set(ARCHITECTURE_GENERIC 1)
|
|
add_definitions(-DARCHITECTURE_GENERIC=1)
|
|
endif()
|
|
message(STATUS "Target architecture: ${ARCHITECTURE}")
|
|
|
|
if (UNIX)
|
|
add_definitions(-DYUZU_UNIX=1)
|
|
endif()
|
|
|
|
# Configure C++ standard
|
|
# ===========================
|
|
|
|
# boost asio's concept usage doesn't play nicely with some compilers yet.
|
|
add_definitions(-DBOOST_ASIO_DISABLE_CONCEPTS)
|
|
if (MSVC)
|
|
add_compile_options($<$<COMPILE_LANGUAGE:CXX>:/std:c++20>)
|
|
|
|
# boost still makes use of deprecated result_of.
|
|
add_definitions(-D_HAS_DEPRECATED_RESULT_OF)
|
|
else()
|
|
set(CMAKE_CXX_STANDARD 20)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
endif()
|
|
|
|
# Output binaries to bin/
|
|
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/bin)
|
|
|
|
# System imported libraries
|
|
# =======================================================================
|
|
|
|
# Enforce the search mode of non-required packages for better and shorter failure messages
|
|
find_package(Boost 1.79.0 REQUIRED context)
|
|
find_package(enet 1.3 MODULE)
|
|
find_package(fmt 9 REQUIRED)
|
|
find_package(inih 52 MODULE COMPONENTS INIReader)
|
|
find_package(LLVM MODULE COMPONENTS Demangle)
|
|
find_package(lz4 REQUIRED)
|
|
find_package(nlohmann_json 3.8 REQUIRED)
|
|
find_package(Opus 1.3 MODULE)
|
|
find_package(ZLIB 1.2 REQUIRED)
|
|
find_package(zstd 1.5 REQUIRED)
|
|
|
|
if (NOT YUZU_USE_EXTERNAL_VULKAN_HEADERS)
|
|
find_package(Vulkan 1.3.246 REQUIRED)
|
|
endif()
|
|
|
|
if (ENABLE_LIBUSB)
|
|
find_package(libusb 1.0.24 MODULE)
|
|
endif()
|
|
|
|
if (ARCHITECTURE_x86 OR ARCHITECTURE_x86_64)
|
|
find_package(xbyak 6 CONFIG)
|
|
endif()
|
|
|
|
if (ARCHITECTURE_x86_64 OR ARCHITECTURE_arm64)
|
|
find_package(dynarmic 6.4.0 CONFIG)
|
|
endif()
|
|
|
|
if (ENABLE_CUBEB)
|
|
find_package(cubeb CONFIG)
|
|
endif()
|
|
|
|
if (USE_DISCORD_PRESENCE)
|
|
find_package(DiscordRPC MODULE)
|
|
endif()
|
|
|
|
if (ENABLE_WEB_SERVICE)
|
|
find_package(cpp-jwt 1.4 CONFIG)
|
|
find_package(httplib 0.12 MODULE COMPONENTS OpenSSL)
|
|
endif()
|
|
|
|
if (YUZU_TESTS)
|
|
find_package(Catch2 3.0.1 REQUIRED)
|
|
endif()
|
|
|
|
# boost:asio has functions that require AcceptEx et al
|
|
if (MINGW)
|
|
find_library(MSWSOCK_LIBRARY mswsock REQUIRED)
|
|
endif()
|
|
|
|
if(ENABLE_OPENSSL)
|
|
find_package(OpenSSL 3.0.0 REQUIRED)
|
|
endif()
|
|
|
|
# Please consider this as a stub
|
|
if(ENABLE_QT6 AND Qt6_LOCATION)
|
|
list(APPEND CMAKE_PREFIX_PATH "${Qt6_LOCATION}")
|
|
endif()
|
|
|
|
function(set_yuzu_qt_components)
|
|
# Best practice is to ask for all components at once, so they are from the same version
|
|
set(YUZU_QT_COMPONENTS2 Core Widgets Concurrent)
|
|
if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
|
|
list(APPEND YUZU_QT_COMPONENTS2 DBus)
|
|
endif()
|
|
if (YUZU_USE_QT_MULTIMEDIA)
|
|
list(APPEND YUZU_QT_COMPONENTS2 Multimedia)
|
|
endif()
|
|
if (YUZU_USE_QT_WEB_ENGINE)
|
|
list(APPEND YUZU_QT_COMPONENTS2 WebEngineCore WebEngineWidgets)
|
|
endif()
|
|
if (ENABLE_QT_TRANSLATION)
|
|
list(APPEND YUZU_QT_COMPONENTS2 LinguistTools)
|
|
endif()
|
|
set(YUZU_QT_COMPONENTS ${YUZU_QT_COMPONENTS2} PARENT_SCOPE)
|
|
endfunction(set_yuzu_qt_components)
|
|
|
|
# Qt5 requires that we find components, so it doesn't fit our pretty little find package function
|
|
if(ENABLE_QT)
|
|
set(QT_VERSION 5.15)
|
|
# These are used to specify minimum versions
|
|
set(QT5_VERSION 5.15)
|
|
set(QT6_VERSION 6.3.1)
|
|
|
|
set_yuzu_qt_components()
|
|
if (ENABLE_QT6)
|
|
find_package(Qt6 ${QT6_VERSION} COMPONENTS ${YUZU_QT_COMPONENTS})
|
|
endif()
|
|
if (Qt6_FOUND)
|
|
message(STATUS "yuzu/CMakeLists.txt: Qt6Widgets_VERSION ${Qt6Widgets_VERSION}, setting QT_VERSION")
|
|
set(QT_VERSION ${Qt6Widgets_VERSION})
|
|
set(QT_MAJOR_VERSION 6)
|
|
# Qt6 sets cxx_std_17 and we need to undo that
|
|
set_target_properties(Qt6::Platform PROPERTIES INTERFACE_COMPILE_FEATURES "")
|
|
else()
|
|
message(STATUS "yuzu/CMakeLists.txt: Qt6 not found/not selected, trying for Qt5")
|
|
# When Qt6 partially found, need this set to use Qt5 when not specifying version
|
|
set(QT_DEFAULT_MAJOR_VERSION 5)
|
|
set(QT_MAJOR_VERSION 5)
|
|
|
|
set(YUZU_USE_QT_MULTIMEDIA ON)
|
|
# Check for system Qt on Linux, fallback to bundled Qt
|
|
if (UNIX AND NOT APPLE)
|
|
if (NOT YUZU_USE_BUNDLED_QT)
|
|
find_package(Qt5 ${QT5_VERSION} COMPONENTS Widgets DBus Multimedia)
|
|
endif()
|
|
if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux" AND (NOT Qt5_FOUND OR YUZU_USE_BUNDLED_QT))
|
|
# Check for dependencies, then enable bundled Qt download
|
|
|
|
# Check that the system GLIBCXX version is compatible
|
|
find_program(OBJDUMP objdump)
|
|
if (NOT OBJDUMP)
|
|
message(FATAL_ERROR "Required program `objdump` not found.")
|
|
endif()
|
|
find_library(LIBSTDCXX libstdc++.so.6)
|
|
execute_process(
|
|
COMMAND
|
|
${OBJDUMP} -T ${LIBSTDCXX}
|
|
COMMAND
|
|
grep GLIBCXX_3.4.28
|
|
COMMAND
|
|
sed "s/[0-9a-f]*.* //"
|
|
COMMAND
|
|
sed "s/ .*//"
|
|
COMMAND
|
|
sort -u
|
|
OUTPUT_VARIABLE
|
|
GLIBCXX_MET
|
|
)
|
|
if (NOT GLIBCXX_MET)
|
|
message(FATAL_ERROR "Qt too old or not found, and bundled Qt package is not \
|
|
compatible with this system. Either install Qt ${QT_VERSION}, or provide the path \
|
|
to Qt by setting the variable Qt5_ROOT.")
|
|
endif()
|
|
|
|
# Check for headers
|
|
find_package(PkgConfig REQUIRED)
|
|
pkg_check_modules(QT_DEP_GLU QUIET glu>=9.0.0)
|
|
if (NOT QT_DEP_GLU_FOUND)
|
|
message(FATAL_ERROR "Qt bundled package dependency `glu` not found. \
|
|
Perhaps `libglu1-mesa-dev` needs to be installed?")
|
|
endif()
|
|
pkg_check_modules(QT_DEP_MESA QUIET dri>=20.0.8)
|
|
if (NOT QT_DEP_MESA_FOUND)
|
|
message(FATAL_ERROR "Qt bundled package dependency `dri` not found. \
|
|
Perhaps `mesa-common-dev` needs to be installed?")
|
|
endif()
|
|
|
|
# Check for X libraries
|
|
set(BUNDLED_QT_REQUIREMENTS
|
|
libxcb-icccm.so.4
|
|
libxcb-image.so.0
|
|
libxcb-keysyms.so.1
|
|
libxcb-randr.so.0
|
|
libxcb-render-util.so.0
|
|
libxcb-render.so.0
|
|
libxcb-shape.so.0
|
|
libxcb-shm.so.0
|
|
libxcb-sync.so.1
|
|
libxcb-xfixes.so.0
|
|
libxcb-xinerama.so.0
|
|
libxcb-xkb.so.1
|
|
libxcb.so.1
|
|
libxkbcommon-x11.so.0
|
|
libxkbcommon.so.0
|
|
)
|
|
set(UNRESOLVED_QT_DEPS "")
|
|
foreach (REQUIREMENT ${BUNDLED_QT_REQUIREMENTS})
|
|
find_library(BUNDLED_QT_${REQUIREMENT} ${REQUIREMENT})
|
|
if (NOT BUNDLED_QT_${REQUIREMENT})
|
|
set(UNRESOLVED_QT_DEPS ${UNRESOLVED_QT_DEPS} ${REQUIREMENT})
|
|
endif()
|
|
unset(BUNDLED_QT_${REQUIREMENT})
|
|
endforeach()
|
|
unset(BUNDLED_QT_REQUIREMENTS)
|
|
|
|
if (NOT "${UNRESOLVED_QT_DEPS}" STREQUAL "")
|
|
message(FATAL_ERROR "Bundled Qt package missing required dependencies: ${UNRESOLVED_QT_DEPS}")
|
|
endif()
|
|
|
|
set(YUZU_USE_BUNDLED_QT ON CACHE BOOL "Download bundled Qt" FORCE)
|
|
endif()
|
|
if (YUZU_USE_BUNDLED_QT)
|
|
# Binary package currently does not support Qt webengine, so make sure it's disabled
|
|
set(YUZU_USE_QT_WEB_ENGINE OFF CACHE BOOL "Use Qt Webengine" FORCE)
|
|
endif()
|
|
endif()
|
|
|
|
set(YUZU_QT_NO_CMAKE_SYSTEM_PATH)
|
|
|
|
if(YUZU_USE_BUNDLED_QT)
|
|
if ((MSVC_VERSION GREATER_EQUAL 1920 AND MSVC_VERSION LESS 1940) AND ARCHITECTURE_x86_64)
|
|
set(QT_BUILD qt-5.15.2-msvc2019_64)
|
|
elseif ((${CMAKE_SYSTEM_NAME} STREQUAL "Linux") AND NOT MINGW AND ARCHITECTURE_x86_64)
|
|
set(QT_BUILD qt5_5_15_2)
|
|
else()
|
|
message(FATAL_ERROR "No bundled Qt binaries for your toolchain. Disable YUZU_USE_BUNDLED_QT and provide your own.")
|
|
endif()
|
|
|
|
if (DEFINED QT_BUILD)
|
|
download_bundled_external("qt/" ${QT_BUILD} QT_PREFIX)
|
|
endif()
|
|
|
|
set(QT_PREFIX_HINT HINTS "${QT_PREFIX}")
|
|
|
|
set(YUZU_QT_NO_CMAKE_SYSTEM_PATH "NO_CMAKE_SYSTEM_PATH")
|
|
# Binary package for Qt5 has Qt Multimedia
|
|
set(YUZU_USE_QT_MULTIMEDIA ON CACHE BOOL "Use Qt Multimedia" FORCE)
|
|
endif()
|
|
|
|
set_yuzu_qt_components()
|
|
find_package(Qt5 ${QT5_VERSION} COMPONENTS ${YUZU_QT_COMPONENTS} ${QT_PREFIX_HINT} ${YUZU_QT_NO_CMAKE_SYSTEM_PATH})
|
|
endif()
|
|
|
|
endif()
|
|
|
|
# find SDL2 exports a bunch of variables that are needed, so its easier to do this outside of the yuzu_find_package
|
|
if (ENABLE_SDL2)
|
|
if (YUZU_USE_BUNDLED_SDL2)
|
|
# Detect toolchain and platform
|
|
if ((MSVC_VERSION GREATER_EQUAL 1920 AND MSVC_VERSION LESS 1940) AND ARCHITECTURE_x86_64)
|
|
set(SDL2_VER "SDL2-2.0.18")
|
|
else()
|
|
message(FATAL_ERROR "No bundled SDL2 binaries for your toolchain. Disable YUZU_USE_BUNDLED_SDL2 and provide your own.")
|
|
endif()
|
|
|
|
if (DEFINED SDL2_VER)
|
|
download_bundled_external("sdl2/" ${SDL2_VER} SDL2_PREFIX)
|
|
endif()
|
|
|
|
set(SDL2_FOUND YES)
|
|
set(SDL2_INCLUDE_DIR "${SDL2_PREFIX}/include" CACHE PATH "Path to SDL2 headers")
|
|
set(SDL2_LIBRARY "${SDL2_PREFIX}/lib/x64/SDL2.lib" CACHE PATH "Path to SDL2 library")
|
|
set(SDL2_DLL_DIR "${SDL2_PREFIX}/lib/x64/" CACHE PATH "Path to SDL2.dll")
|
|
|
|
add_library(SDL2::SDL2 INTERFACE IMPORTED)
|
|
target_link_libraries(SDL2::SDL2 INTERFACE "${SDL2_LIBRARY}")
|
|
target_include_directories(SDL2::SDL2 INTERFACE "${SDL2_INCLUDE_DIR}")
|
|
elseif (YUZU_USE_EXTERNAL_SDL2)
|
|
message(STATUS "Using SDL2 from externals.")
|
|
else()
|
|
find_package(SDL2 2.0.18 REQUIRED)
|
|
endif()
|
|
endif()
|
|
|
|
# List of all FFmpeg components required
|
|
set(FFmpeg_COMPONENTS
|
|
avcodec
|
|
avfilter
|
|
avutil
|
|
swscale)
|
|
|
|
if (UNIX AND NOT APPLE AND NOT ANDROID)
|
|
find_package(PkgConfig REQUIRED)
|
|
pkg_check_modules(LIBVA libva)
|
|
endif()
|
|
if (NOT YUZU_USE_BUNDLED_FFMPEG)
|
|
# Use system installed FFmpeg
|
|
find_package(FFmpeg 4.3 REQUIRED QUIET COMPONENTS ${FFmpeg_COMPONENTS})
|
|
endif()
|
|
|
|
# Prefer the -pthread flag on Linux.
|
|
set(THREADS_PREFER_PTHREAD_FLAG ON)
|
|
find_package(Threads REQUIRED)
|
|
|
|
# Platform-specific library requirements
|
|
# ======================================
|
|
|
|
if (APPLE)
|
|
# Umbrella framework for everything GUI-related
|
|
find_library(COCOA_LIBRARY Cocoa)
|
|
set(PLATFORM_LIBRARIES ${COCOA_LIBRARY} ${IOKIT_LIBRARY} ${COREVIDEO_LIBRARY})
|
|
elseif (WIN32)
|
|
# Target Windows 10
|
|
add_definitions(-D_WIN32_WINNT=0x0A00 -DWINVER=0x0A00)
|
|
set(PLATFORM_LIBRARIES winmm ws2_32 iphlpapi)
|
|
if (MINGW)
|
|
# PSAPI is the Process Status API
|
|
set(PLATFORM_LIBRARIES ${PLATFORM_LIBRARIES} psapi imm32 version)
|
|
endif()
|
|
|
|
if (YUZU_CRASH_DUMPS)
|
|
find_library(DBGHELP_LIBRARY dbghelp)
|
|
if ("${DBGHELP_LIBRARY}" STREQUAL "DBGHELP_LIBRARY-NOTFOUND")
|
|
message(FATAL_ERROR "YUZU_CRASH_DUMPS enabled but dbghelp library not found")
|
|
endif()
|
|
endif()
|
|
elseif (CMAKE_SYSTEM_NAME MATCHES "^(Linux|kFreeBSD|GNU|SunOS)$")
|
|
set(PLATFORM_LIBRARIES rt)
|
|
endif()
|
|
|
|
# Setup a custom clang-format target (if clang-format can be found) that will run
|
|
# against all the src files. This should be used before making a pull request.
|
|
# =======================================================================
|
|
|
|
set(CLANG_FORMAT_POSTFIX "-15")
|
|
find_program(CLANG_FORMAT
|
|
NAMES clang-format${CLANG_FORMAT_POSTFIX}
|
|
clang-format
|
|
PATHS ${PROJECT_BINARY_DIR}/externals)
|
|
# if find_program doesn't find it, try to download from externals
|
|
if (NOT CLANG_FORMAT)
|
|
if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
|
|
message(STATUS "Clang format not found! Downloading...")
|
|
set(CLANG_FORMAT "${PROJECT_BINARY_DIR}/externals/clang-format${CLANG_FORMAT_POSTFIX}.exe")
|
|
file(DOWNLOAD
|
|
https://github.com/yuzu-emu/ext-windows-bin/raw/master/clang-format${CLANG_FORMAT_POSTFIX}.exe
|
|
"${CLANG_FORMAT}" SHOW_PROGRESS
|
|
STATUS DOWNLOAD_SUCCESS)
|
|
if (NOT DOWNLOAD_SUCCESS EQUAL 0)
|
|
message(WARNING "Could not download clang format! Disabling the clang format target")
|
|
file(REMOVE ${CLANG_FORMAT})
|
|
unset(CLANG_FORMAT)
|
|
endif()
|
|
else()
|
|
message(WARNING "Clang format not found! Disabling the clang format target")
|
|
endif()
|
|
endif()
|
|
|
|
if (CLANG_FORMAT)
|
|
set(SRCS ${PROJECT_SOURCE_DIR}/src)
|
|
set(CCOMMENT "Running clang format against all the .h and .cpp files in src/")
|
|
if (WIN32)
|
|
add_custom_target(clang-format
|
|
COMMAND powershell.exe -Command "Get-ChildItem '${SRCS}/*' -Include *.cpp,*.h -Recurse | Foreach {&'${CLANG_FORMAT}' -i $_.fullname}"
|
|
COMMENT ${CCOMMENT})
|
|
elseif(MINGW)
|
|
add_custom_target(clang-format
|
|
COMMAND find `cygpath -u ${SRCS}` -iname *.h -o -iname *.cpp | xargs `cygpath -u ${CLANG_FORMAT}` -i
|
|
COMMENT ${CCOMMENT})
|
|
else()
|
|
add_custom_target(clang-format
|
|
COMMAND find ${SRCS} -iname *.h -o -iname *.cpp | xargs ${CLANG_FORMAT} -i
|
|
COMMENT ${CCOMMENT})
|
|
endif()
|
|
unset(SRCS)
|
|
unset(CCOMMENT)
|
|
endif()
|
|
|
|
# Include source code
|
|
# ===================
|
|
|
|
# This function should be passed a list of all files in a target. It will automatically generate
|
|
# file groups following the directory hierarchy, so that the layout of the files in IDEs matches the
|
|
# one in the filesystem.
|
|
function(create_target_directory_groups target_name)
|
|
# Place any files that aren't in the source list in a separate group so that they don't get in
|
|
# the way.
|
|
source_group("Other Files" REGULAR_EXPRESSION ".")
|
|
|
|
get_target_property(target_sources "${target_name}" SOURCES)
|
|
|
|
foreach(file_name IN LISTS target_sources)
|
|
get_filename_component(dir_name "${file_name}" PATH)
|
|
# Group names use '\' as a separator even though the entire rest of CMake uses '/'...
|
|
string(REPLACE "/" "\\" group_name "${dir_name}")
|
|
source_group("${group_name}" FILES "${file_name}")
|
|
endforeach()
|
|
endfunction()
|
|
|
|
# Prevent boost from linking against libs when building
|
|
target_link_libraries(Boost::headers INTERFACE Boost::disable_autolinking)
|
|
# Adjustments for MSVC + Ninja
|
|
if (MSVC AND CMAKE_GENERATOR STREQUAL "Ninja")
|
|
add_compile_options(
|
|
/wd4464 # relative include path contains '..'
|
|
/wd4711 # function 'function' selected for automatic inline expansion
|
|
/wd4820 # 'bytes' bytes padding added after construct 'member_name'
|
|
)
|
|
endif()
|
|
|
|
if (YUZU_USE_FASTER_LD AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
|
|
# We will assume that if the compiler is GCC, it will attempt to use ld.bfd by default.
|
|
# Try to pick a faster linker.
|
|
find_program(LLD lld)
|
|
find_program(MOLD mold)
|
|
|
|
if (MOLD AND CMAKE_CXX_COMPILER_VERSION VERSION_GREATER_EQUAL "12.1")
|
|
message(NOTICE "Selecting mold as linker")
|
|
add_link_options("-fuse-ld=mold")
|
|
elseif (LLD)
|
|
message(NOTICE "Selecting lld as linker")
|
|
add_link_options("-fuse-ld=lld")
|
|
endif()
|
|
endif()
|
|
|
|
add_subdirectory(externals)
|
|
add_subdirectory(src)
|
|
|
|
# Set yuzu project or yuzu-cmd project as default StartUp Project in Visual Studio depending on whether QT is enabled or not
|
|
if(ENABLE_QT)
|
|
set_property(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY VS_STARTUP_PROJECT yuzu)
|
|
else()
|
|
set_property(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} PROPERTY VS_STARTUP_PROJECT yuzu-cmd)
|
|
endif()
|
|
|
|
|
|
# Installation instructions
|
|
# =========================
|
|
|
|
# Install freedesktop.org metadata files, following those specifications:
|
|
# https://specifications.freedesktop.org/desktop-entry-spec/desktop-entry-spec-latest.html
|
|
# https://specifications.freedesktop.org/icon-theme-spec/icon-theme-spec-latest.html
|
|
# https://specifications.freedesktop.org/shared-mime-info-spec/shared-mime-info-spec-latest.html
|
|
# https://www.freedesktop.org/software/appstream/docs/
|
|
if(ENABLE_QT AND UNIX AND NOT APPLE)
|
|
install(FILES "dist/org.yuzu_emu.yuzu.desktop"
|
|
DESTINATION "share/applications")
|
|
install(FILES "dist/yuzu.svg"
|
|
DESTINATION "share/icons/hicolor/scalable/apps"
|
|
RENAME "org.yuzu_emu.yuzu.svg")
|
|
install(FILES "dist/org.yuzu_emu.yuzu.xml"
|
|
DESTINATION "share/mime/packages")
|
|
install(FILES "dist/org.yuzu_emu.yuzu.metainfo.xml"
|
|
DESTINATION "share/metainfo")
|
|
endif()
|